Sub Click(Source As Button)
	'---------- ---------- ---------- ---------- ---------- 
	'YoutubeAPIから取得したレスポンスをMsgboxに表示
	'
	'---------- ---------- ---------- ---------- ---------- 
	Const APIURL		=  "https://www.googleapis.com/youtube/v3/search?key="
	Const APIKEY		= "(取得したAPIKEY)"			'APIKey
	Const CHANNELID	= "(検索したChannelID)"									'ChannelID
	
	'クラス・変数宣言	
	Dim vXml			As Variant					'XMLオブジェクト
	Dim sUrl			As String					'送信するURL
	Dim vResponse		As Variant					'HTTPRequestからの戻り値
	
	'フィールドの値を取得して、リクエストURIを生成(指定のチャンネルから日付の新しい順に取得、件数を指定しないと5件取得される)
	sUrl = APIURL + APIKEY + "&channelId=" +  CHANNELID + "&part=snippet,id&order=date"
	
	'Getリクエストを実行し、結果を取得
	Set vXml = CreateObject("MSXML2.ServerXMLHTTP.6.0")	
	vXml.Open "GET", sUrl, False
	vXml.send ""
	
	Msgbox vXml.responseText
	
	Msgbox "Done!"
	
End Sub

Sub Click(Source As Button)
	'---------- ---------- ---------- ---------- ---------- 
	'YoutubeAPIから取得したレスポンスをJSONに分解し、文書として登録
	'
	'---------- ---------- ---------- ---------- ---------- 
	Const APIURL		=  "https://www.googleapis.com/youtube/v3/search?key="
	Const APIKEY		= "(取得したAPIKEY)"			'APIKey
	Const CHANNELID	= "(検索したChannelID)"									'ChannelID
	
	'クラス・変数宣言
	Dim session		As New NotesSession
	Dim db				As NotesDatabase
	Dim doc			As NotesDocument
	Dim jsonNav		As NotesJSONNavigator
	
	Dim vXml			As Variant					'XMLオブジェクト
	Dim sUrl			As String					'送信するURL
	Dim vResponse		As Variant					'HTTPRequestからの戻り値
	Dim iItemCnt		As Integer					'JSONオブジェクト件数
	Dim iCnt			As Integer					'ループカウンタ
	
	'フィールドの値を取得して、リクエストURIを生成(指定のチャンネルから日付の新しい順に取得、件数を指定しないと5件取得される)
	sUrl = APIURL + APIKEY + "&channelId=" +  CHANNELID + "&part=snippet,id&order=date"
	
	'Getリクエストを実行し、結果を取得
	Set vXml = CreateObject("MSXML2.ServerXMLHTTP.6.0")	
	vXml.Open "GET", sUrl, False
	vXml.send ""
	
	'レスポンスをJSONナビゲータに格納、リストの数を取得
	Set jsonNav	= session.CreateJSONNavigator(vXml.responseText)
	iItemCnt		= jsonNav.GetElementByName("items").Value.Size
	
	'文書を作成し、Responseを保存
	For iCnt = 0 To iItemCnt - 1	
		Set db			= session.CurrentDatabase
		Set doc		= db.CreateDocument
		
		doc.Form			= "frmLevel2"
		doc.Title			= jsonNav.GetElementByPointer("/items/" & Cstr(iCnt) & "/snippet/title").Value
		doc.VideoId			= jsonNav.GetElementByPointer("/items/" & Cstr(iCnt) & "/id/videoId").Value
		doc.Thumbnail		= jsonNav.GetElementByPointer("/items/" & Cstr(iCnt) & "/snippet/thumbnails/default/url").Value
		doc.ChannelTitle	= jsonNav.GetElementByPointer("/items/" & Cstr(iCnt) & "/snippet/channelTitle").Value
		doc.Response		= vXml.responseText & Chr(13) & "<" & Cstr(iCnt) & ">"
		
		Call doc.Save(True,True)
	Next
	
	Msgbox "Done!"
End Sub

Sub Click(Source As Button)
	'---------- ---------- ---------- ---------- ---------- 
	'YoutubeAPIから取得したレスポンスをJSONに分解し、文書として登録
	'
	'---------- ---------- ---------- ---------- ---------- 
	Const APIURL		=  "https://www.googleapis.com/youtube/v3/search?key="
	Const APIKEY		= "(取得したAPIKEY)"			'APIKey
	Const CHANNELID	= "(検索したChannelID)"									'ChannelID
	
	'クラス・変数宣言
	Dim session		As New NotesSession
	Dim db				As NotesDatabase
	Dim doc			As NotesDocument
	Dim jsonNav		As NotesJSONNavigator
	
	Dim vXml			As Variant					'XMLオブジェクト
	Dim sBaseUrl		As String					'ベースURL	
	Dim sUrl			As String					'送信するURL
	Dim vResponse		As Variant					'HTTPRequestからの戻り値
	Dim iItemCnt		As Integer					'JSONオブジェクト件数
	Dim iCnt			As Integer					'ループカウンタ
	Dim sNextPageToken	As String			'次のページを取得するためのトークン
	Dim iTotalCnt		As Integer
	
	'Getリクエストを実行し、結果を取得
	Set vXml = CreateObject("MSXML2.ServerXMLHTTP.6.0")	
	
    ' 初回リクエストのURLを作成
	sBaseUrl	= APIURL +  APIKEY + "&channelId=" +  CHANNELID + "&part=snippet,id&order=date"
	sUrl		= sBaseUrl
	iTotalCnt 	= 0
	'nextPageTokenがnullになるまでループ
	Do	
		vXml.Open "GET", sUrl, False
		vXml.send ""		
		
		'リクエスト越えチェック
		If vXml.Status = 403 Then
			Msgbox "リクエスト越え",16,"Error"
			Exit Sub
		End If
		
		'レスポンスをJSONナビゲータに格納、リストの数を取得
		Set jsonNav	= session.CreateJSONNavigator(vXml.responseText)
		iItemCnt		= jsonNav.GetElementByName("items").Value.Size
		sNextPageToken	= jsonNav.GetElementByPointer("/nextPageToken").value
		
		'文書を作成し、Responseを保存(一度のResponseを分解)
		For iCnt = 0 To iItemCnt - 1	
			Set db			= session.CurrentDatabase
			Set doc		= db.CreateDocument
			
			doc.Form			= "frmLevel2"
			doc.Title			= jsonNav.GetElementByPointer("/items/" & Cstr(iCnt) & "/snippet/title").Value
			doc.VideoId			= jsonNav.GetElementByPointer("/items/" & Cstr(iCnt) & "/id/videoId").Value
			doc.Thumbnail		= jsonNav.GetElementByPointer("/items/" & Cstr(iCnt) & "/snippet/thumbnails/default/url").Value
			doc.ChannelTitle	= jsonNav.GetElementByPointer("/items/" & Cstr(iCnt) & "/snippet/channelTitle").Value
			doc.Response		= vXml.responseText & Chr(13) & "<" & Cstr(iCnt) & ">"
			
			Call doc.Save(True,True)
		Next
		
		'nextPageTokenを引数に渡し、次のURLを生成
		sUrl = sBaseUrl & "&pageToken=" & sNextPageToken
		
		iTotalCnt	= iTotalCnt + 1
		If iTotalCnt > 3 Then
			Exit Sub
		End If
		
	Loop While(sNextPageToken <> "")
	
	Msgbox "Done!"
	
End Sub