{
    "model": "gpt-4o-2024-05-13",
    "messages": [
        {
            "role": "user",
            "content": [
                {
                    "type": "text",
                    "text": "何が描かれていますか？詳しく日本語で教えて下さい。"
                },
                {
                    "type": "image_url",
                    "image_url": {
                        "url": "data:image/jpeg;base64,{base64_image}"
                    }
                }
            ]
        }
    ]
}

Sub Click(Source As Button)
	'---------- ---------- ---------- ---------- ---------- 
	'OpenAI APIから取得したレスポンスを書込み
	'
	'---------- ---------- ---------- ---------- ---------- 	
	Const APIURL = "https://api.openai.com/v1/chat/completions"
	Const APIKEY = "(取得したAPIKEY)"
	Const MODEL = "gpt-4o-2024-05-13"
	
	'クラス・変数宣言	
	Dim ws				As New NotesUIWorkspace
	Dim uidoc			As NotesUIDocument
	Dim doc			As NotesDocument
	Dim session		As New NotesSession
	Dim http			As NotesHTTPRequest
	Dim jsonNav		As NotesJSONNavigator
	Dim stream			As NotesStream			'画像ファイル読み込み	
	
	Dim sRequest		As String					'入力した質問
	Dim sBodyJson		As String					'送信するJSON文字列
	Dim sContent		As String					'回答本文
	Dim vResHeader	As Variant					'httpレスポンスヘッダー全体
	Dim vResCode		As Variant					'httpレスポンスヘッダー0行目リスト
	Dim iResCode		As Integer					'httpレスポンスコード
	Dim sImagePath	As String					'画像ファイルパス
	Dim sBase64Str	As String					'Base64変換後ファイル
	Dim sMediaType	As String					'メディアタイプ(POSTで使用)
	
	'クラス・変数セット
	Set http		= session.CreateHTTPRequest()	
	Set uidoc		= ws.CurrentDocument
	Set doc		= uidoc.Document
	
	'入力チェック
	sRequest		= doc.Request(0)
	If sRequest = "" Then
		Msgbox "質問を入力して下さい。"
		Exit Sub
	End If
	sImagePath		= doc.ImagePath(0)
	If sImagePath = "" Then
		Msgbox "画像ファイルパスを入力して下さい。"
		Exit Sub
	End If	
	
	
	'画像ファイルの読み込みとBase64エンコード
	Set stream			= session.CreateStream()
	Call stream.Open(sImagePath, "binary")
	sBase64Str = Replace(stream.ReadEncoded(ENC_BASE64, 76), Chr(13) & Chr(10) , "")		'裏コード
	
	'画像ファイルのMediaType決定
	sMediaType		= GetMediaType(sImagePath)		
	
	'Getリクエストを実行し、結果を取得
	Call http.SetHeaderField("Content-Type", "application/json") 
	Call http.SetHeaderField("Authorization", "Bearer " & APIKEY) 
	http.PreferJSONNavigator	= True
	
	'特殊文字対策
	sRequest = ReplaceSpecialCharacters(sRequest)
	
	'リクエスト送信
	sBodyJson		= |{"model":"| & MODEL & |", "messages":[| _
	& |{"role":"user", "content":[| _
	& |{"type":"text","text":"| & sRequest & |"},| _
	& |{"type":"image_url","image_url": {| _
	& |"url": "data:| & sMediaType & |;base64,|& sBase64Str & |"| _
	& |} }| _
	& |] }| _
	& |] }|
	Set jsonNav	= http.post(APIURL, sBodyJson)
	
	'エラーレスポンスチェック
	vResHeader	= http.GetResponseHeaders()
	vResCode		= Split(vResHeader(0)," ")
	iResCode		= Cint(vResCode(1))	
	If iResCode <> 200 Then
		Msgbox  sContent , 16 , "Error : " & Cstr(iResCode)
		Exit Sub
	End If
	
	'レスポンスから回答を抽出
	sContent		= jsonNav.GetElementByPointer("/choices/0/message/content").Value
	
	'回答をフォームに書込み
	doc.HttpStatus	= iResCode
	doc.Response	= sContent
	
	Exit Sub
	
ErrRtn:              'エラールーチン
	Msgbox Error() & Chr(13) & "Line: " & Erl(), 16, "Error"
	Print Error(), "ErrorCode: " & Err(), "Line: " & Erl()
	Print "モジュール: 送信でエラーが発生しました。"
	End
	
End Sub


Function GetMediaType(sFilePath As String) As String
	'---------- ---------- ---------- ---------- ---------- 
	' ファイルの拡張子からMediaTypeを決定する
	' 引数：
	' 戻り値：MediaType(image/jpeg、image/png、image/gif、image/webp
	'---------- ---------- ---------- ---------- ---------- 
	Dim sExt			As String		'拡張子
	Dim sMediaType	As String		'メディアタイプ
	
	sExt	= Lcase(Strrightback(sFilePath , "."))
	
	Select Case sExt
	Case "jpg","jpeg":
		sMediaType		= "image/jpeg"
	Case "png":
		sMediaType		= "image/png"
	Case "gif":
		sMediaType		= "image/gif"
	Case "webp":
		sMediaType		= "image/webp"
	Case Else
		sMediaType		= "Unknown"
	End Select
	
	GetMediaType		= sMediaType
	
End Function



'<<<<<<<<<< ReplaceSpecialCharacters関数は省略 >>>>>>>>>>